I = 2 x 4 x T x P0 x V0 x ( 2 x P1 x V1 - 1 ),
где: P0 и P1 - начальные значения предделителей;
V0 и V1 - начальные значения счетчиков;
T - период частоты генератора XTAL.
Минимальный интервал на частоте 8 МГц составит
Imin = 2 x 4 x 1/8 x 1 x 1 x ( 2 x 1 x 1 - 1 ) = 1 мкс,
а максимальный
Imax = 2 x 4 x 1/8 x 64 x 256 x ( 2 x 64 x 256 - 1) = 536,854528 с.

Ниже приведен текст подпрограммы инициализации каскадирован¬ных таймеров для обеспечения задержки в 1.998 с.
;Подпрограмма задержки 1.998 с.
TIMER: LD PRE1,#00101000B ; Модуль пересчета предделителя
; T1=10, синхронизация - внешняя,
; режим - однопроходный
LD P3M,#01H ; P36 - выход TOUT
LD T1,#64H ; Начальное значение T1=100
LD PRE0,#00101001B ; Модуль пересчета предделителя
; T0=10, режим циклический
LD T0,#64H ; Начальное значение T0=100
DI
AND IMR,#00101011B ; Запретить IRQ2 и IRQ4,
OR IMR,#00100000B ; Разрешить IRQ5
EI
LD TMR,#01001111B ; Выход TOUT управляется с
; выхода T0, синхронизация T1 со
; входа TIN, загрузка и разрешение
; счета T0 и T1
RET
.END
Контроль синхронизации
Таймер/счетчик T1 и вход TIN могут быть использованы для контроля за линией синхронизации (например, в контроллере диско¬вода гибкого диска) путем генерирования запроса на прерывание, если синхроимпульс пропадает. Для выполнения этого, контролируе¬мая линия синхронизации подсоединяется проводником к выводу Р31
(TIN). Вход TIN должен быть запрограммирован как вход перезапуска
T1, т.е. так, чтобы каждый падающий фронт сигнала на TIN застав¬лял бы T1 перезагрузиться и продолжать счет. Если T1 запрограмми¬рован на переполнение по истечении интервала времени в 1.5 перио¬да контролируемой последовательности синхроимпульсов, то он дос¬тигнет конца счета и сгенерирует запрос прерывания IRQ5 только при попадании импульса синхронизации.
Приведенная ниже программа включает подпрограмму инициализа¬ции T1 и TIN (MONITOR_INT) для контроля за синхронизацией с пери¬одом в 2 мкс. Предполагается, что частота генератора XTAL=8 МГц. Следует отметить, что в этом случае лучше выбрать однопроходный, чем циклический режим для таймера T1. Это предотвратит непрерыв¬ный поток запросов прерывания IRQ5 в случае, когда контролируемая синхронизация полностью выключится. Лучше, если подпрограмма об¬работки прерывания (CLK_ERR) сделает выбор, когда следует, а ког¬да не следует возобновить контроль. В программе показан также вектор прерывания от таймера/счетчика T1 (IRQ_5).
; Программа контроля синхронизации
.ORG 0010
IRQ_5: .WORD CLK_ERR
.ORG 000CH
; Подпрограмма инициализации таймера
MONITOR_INT:
LD PRE1,#00000100B ; Модуль предделителя T1=1,
; синхронизация внешняя,
; режим - однопроходный
LD P3M,#01H ; Р36 - выход TUOT
LD T1,#03H ; Начальное значение
; таймера T1=1,5.2 мкс
DI
AND IMR,#00111011B ; Запретить IRQ2
OR IMR,#00100000B ; Разрешить IRQ5
EI
LD TMR,#00111000B ; Режим перезапуска
; от TIN, разрешить T1
RET
; Подпрограмма обслуживания прерывания IRQ5
CLK_ERR:
...................... ; Обработать ситуацию
...................... ; пропадания импульса
; если контроль нужно продолжить ...
OR TMR,#00001000B ; Разрешить T1
IRET
.END
ЛИТЕРАТУРА
1. Гладштейн М.А. Изучаем микроконтроллеры Z8. Часть 4. Таймеры/счетчики.- Радио, 1998, N 10.